|
一个使用JMAIL发信的例子
常常有朋友询问到底如何使用JMAIL发送电子邮件，如何实现网上表单的提交，下面我举一个例子。
请从以下地址下载这个例子：
http://www.ajiang.net/luntan/lianxi.zip
（代码附后，可不下载直接阅读）
1、代码的HTML部分将5个表单项（姓名、电子邮件、其他联系方法、主题、内容）分别以T1～T5为name提交给lianxi.asp。
2、程序部分用request属性获得表单内容，然后把相应的值赋给相应的JMAIL对象属性。
3、下面详细说说SMTP发信认证问题：
为了阻止垃圾邮件防止滥用免费邮箱服务器，各免费信箱网站都推出了SMTP发信认证，这在使用WEB方式收发邮件时是感觉不到的，只有使用发信软件通过SMTP连接发信时才会遇到，就是SMTP（发信）服务器要求你告诉他你的用户名和密码，否则服务器将拒绝发送你的邮件，而且多数SMTP服务器还要验证一下发信人地址，比如你使用smtp.163.net这个服务器发信，他要求发信人地址必须是****@163.net，否则同样要拒绝发信。
当我们使用这样的SMTP服务器时，我们必须使用JMAIL4.0以上版本的MESSAGE对象来发信，有关发信认证在代码中的用法大家可以参考例子。
下面的例子是一个简单的应用，界面很简单，大家可以根据自己的需要修改外观。
注意：收信人电子邮件地址一定要修改为你的地址！
<!--lianxi.asp-->
<%@ Language=VBScript %>
<%
'==================================================
' 参 数 设 置
'==================================================
'收信人电子邮件地址
'表单里的内容将发送到这个信箱中
myemail ="info@ajiang.net"
'收信人姓名
myname ="阿江"
'所使用的SMTP服务器
smtpserver ="smtp.163.net"
'如果SMTP服务器需要发信认证，则设置登录SMTP服务器的用户名和密码
smtpuser ="zjyfc"
smtppwd ="这里填写密码"
'与相应SMTP服务器对应的邮件地址
'注意：很多SMTP服务器除了要验证用户名和密码外，还要验证发件人地
'址，比如163.net的SMTP服务器在检查发信人邮件地址是不是以163.net
'结尾，否则不予发送，因此，使用相应的信箱做为发信人信箱是必要的
smtpemail ="zjyfc@163.net"
'==================================================
' 程 序 开 始
'==================================================
tname =Request("t1")
temail =Request("t2")
tother =Request("t3")
tsubject =Request("t4")
tbody =Request("t5")
if tname <> "" and temail <> "" then
set jmail=server.CreateObject ("jmail.message")
jmail.Silent =true
jmail.Charset ="gb2312"
if smtpemail <> "" then
jmail.From ="zjyfc@163.net"
else
jmail.From =temail
end if
jmail.FromName =tname
jmail.ReplyTo =temail
jmail.Subject ="网上提交：" & tsubject
jmail.AddRecipient myemail,myname
jmail.Body =tbody & vbcrlf & vbcrlf & "其他联系方式：" & tother
jmail.MailServerUserName =smtpuser
jmail.MailServerPassWord =smtppwd
isgo=jmail.Send(smtpserver)
if isgo then
msg="提交成功！谢谢你的支持。"
else
msg="发送失败！请检查您的邮件地址是否填写正确。"
end if
jmail.Close
set jmail=nothing
end if
%>
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<title>与阿江联系</title>
<LINK rel="stylesheet" type="text/css" href="style.css">
</head>
<body>
<form action=lianxi.asp>
<br><%=msg%>
<br>姓名：
<br><input name=T1 size=10>
<br>电子邮件：
<br><input name=T2 size=30>
<br>其他联系方式：
<br><input name=T3 size=30>
<br>主题：
<br><input name=T4 size=30>
<br>正文：
<br><TEXTAREA rows=4 cols=25 name=T5>
</TEXTAREA>
<br><INPUT type="submit" value="确定">
</form>
</body></html>
发表时间：2002-4-7 11:45:27 点击：37064
[返回上一页]返回
[回阿江守候首页]
[回阿江动态栏目]
| 
